Switching Things On And Off With An Arduino: Multiple states from a single push button switch

// Define the pins being used
int pin_LEDgreen = 10;
int pin_LEDyellow = 9;
int pin_LEDred = 8;

The pins are then initialized and set LOW in the setup() function.

pinMode(pin_LEDgreen, OUTPUT);    digitalWrite(pin_LEDgreen,LOW); 
pinMode(pin_LEDyellow, OUTPUT);   digitalWrite(pin_LEDyellow,LOW); 
pinMode(pin_LEDred, OUTPUT);      digitalWrite(pin_LEDred,LOW);

To keep track of where we are, a new variable called state is used. state is a byte that can have 1 of 4 values (0 to 3):
– state = 0 – all LEDs off
– state = 1 – green LED on
– state = 2 – yellow LED on
– state = 3 – red LED on

Every time the button switch is pressed the value of state is increased by 1. When state is greater than 3 it is reset to 0.

// increase the value of state
state++;
if (state > 3) { state = 0; }

“state++” is exactly the same as “state = state + 1”

I have kept the logic as simple as possible and the LEDs are controlled with a series of if statements. Since state can only have 1 value at a time and the value does not change within the IFs I do not need to use else if, a simple list of basic if statements is all that is required. You could also use a switch/case statement.

if (state==1) { digitalWrite(pin_LEDgreen, HIGH);  }
if (state==2) { digitalWrite(pin_LEDyellow, HIGH);  }
if (state==3) { digitalWrite(pin_LEDred, HIGH);  }

There are different ways to do this but, as always, I like to keep it simple and straight forward and believe when learning it is important to understand what is happening so that you can get things working as quickly as possible. If the code is unnecessarily complex you may be able to copy and paste it but you won’t understand it and so you won’t be able to adapt it to your own needs.

If I were using more LEDs I would put the pin values in an array and then use the state variable as the array index. See example below.

Sketch: Multiple states from a single button switch

//  Sketch: Multiple states from a single button switch
//  www.martyncurrey.com
//
//  An  example of using a single button switch to set multiple states or conditions
//
//  Pins
//  D10 to resister and green LED
//  D9 to resister and yellow LED
//  D8 to resister and red LED
//  D2 to push button switch
//  
//  state holds the current status.
//  0 = all off.
//  1 = green LED
//  2 = yellow LED
//  3 = red LED
 
// Define the pins being used
int pin_LEDgreen = 10;
int pin_LEDyellow = 9;
int pin_LEDred = 8;
 
int pin_switch = 2;
 
// variables to hold the new and old switch states
boolean oldSwitchState = LOW;
boolean newSwitchState1 = LOW;
boolean newSwitchState2 = LOW;
boolean newSwitchState3 = LOW;
 
byte state = 0;
 
void setup() 
{
    Serial.begin(9600);
    Serial.print("Sketch:   ");   Serial.println(__FILE__);
    Serial.print("Uploaded: ");   Serial.println(__DATE__);
    Serial.println(" ");
 
    pinMode(pin_LEDgreen, OUTPUT);    digitalWrite(pin_LEDgreen,LOW); 
    pinMode(pin_LEDyellow, OUTPUT);   digitalWrite(pin_LEDyellow,LOW); 
    pinMode(pin_LEDred, OUTPUT);      digitalWrite(pin_LEDred,LOW); 
 
    pinMode(pin_switch, INPUT); 
}
 
void loop()
{
    newSwitchState1 = digitalRead(pin_switch);
    delay(1);
    newSwitchState2 = digitalRead(pin_switch);
    delay(1);
    newSwitchState3 = digitalRead(pin_switch);
 
    // if all 3 values are the same we can continue
    if (  (newSwitchState1==newSwitchState2) && (newSwitchState1==newSwitchState3) )
    {
 
        if ( newSwitchState1 != oldSwitchState ) 
        {
 
           // has the button switch been closed?
           if ( newSwitchState1 == HIGH )
           {
                // increase the value of state
                state++;
                if (state > 3) { state = 0; }
 
                // turn all LEDs off. Doing it this way means we do not need to care about the individual LEDs
                // simply turn them all off and then turn on the correct one. 
                digitalWrite(pin_LEDgreen, LOW);
                digitalWrite(pin_LEDyellow, LOW);
                digitalWrite(pin_LEDred, LOW);
 
                // Turn on the next LED
                // Because the value of state does not change while we are testing it we don't need to use else if
                if (state==1) { digitalWrite(pin_LEDgreen, HIGH);  }
                if (state==2) { digitalWrite(pin_LEDyellow, HIGH);  }
                if (state==3) { digitalWrite(pin_LEDred, HIGH);  }
 
           }
           oldSwitchState = newSwitchState1;
        }  
    }
}

char LED_Pins_array[] = { 10, 9, 8};
 
char LED_Sequence_array[] = { 10, 9, 8, 9};
byte squenceLength = 4;

Now that there is an an array holding the pin numbers, we can use it when initializing the pins.

for (byte i=0; i< 3; i++)
{    
      pinMode(LED_Pins_array[i], OUTPUT);    digitalWrite(LED_Pins_array[i],LOW); 
}

In the loop() function, now that we have a variable storing the length of the LED sequence array and it can be used reset the state variable. Remember that arrays in C start at position 0 so we need to reduce the squenceLength value by 1.

state++;
if (state > (squenceLength -1) ) { state = 0; }

The LED sequence array, with the state variable as the index, can be used for the pin number to turn on the next LED.

digitalWrite(LED_Sequence_array[state],HIGH);

LED_Sequence_array[] holds the pin number to use.